raylib Quick Reference

Signatures below are taken from the bindings that ship with the compiler (/usr/lib/odin/vendor/raylib/raylib.odin, raylib 6.0). rl is the conventional alias for import rl "vendor:raylib".

grep -n "Draw.*Circle" /usr/lib/odin/vendor/raylib/raylib.odin
grep -n "Collision"    /usr/lib/odin/vendor/raylib/raylib.odin

The skeleton

package main

import rl "vendor:raylib"

main :: proc() {
	rl.SetConfigFlags({.VSYNC_HINT})       // before InitWindow
	rl.InitWindow(960, 540, "Title")
	defer rl.CloseWindow()

	rl.InitAudioDevice()                   // only if you need sound
	defer rl.CloseAudioDevice()

	for !rl.WindowShouldClose() {
		dt := rl.GetFrameTime()
		// update

		rl.BeginDrawing()
		defer rl.EndDrawing()

		rl.ClearBackground(rl.RAYWHITE)
		// draw

		free_all(context.temp_allocator)
	}
}

Core types

Vector2   :: [2]f32                       // an array, so + - * / work component-wise
Color     :: distinct [4]u8               // r, g, b, a

Rectangle :: struct { x, y, width, height: f32 }   // x,y is the TOP-LEFT corner

Camera2D :: struct {
	offset:   Vector2,    // where `target` lands on screen
	target:   Vector2,    // world point the camera looks at
	rotation: f32,        // degrees
	zoom:     f32,        // 1.0 is unscaled — a zoom of 0 draws nothing
}

Built-in colours: RAYWHITE WHITE BLACK BLANK LIGHTGRAY GRAY DARKGRAY YELLOW GOLD ORANGE PINK RED MAROON GREEN LIME DARKGREEN SKYBLUE BLUE DARKBLUE PURPLE VIOLET DARKPURPLE BEIGE BROWN DARKBROWN MAGENTA. Build your own with rl.Color{40, 42, 54, 255}, or fade one with rl.Fade(rl.RED, 0.5).

Window and timing

Useful ConfigFlag members: .VSYNC_HINT .WINDOW_RESIZABLE .MSAA_4X_HINT .FULLSCREEN_MODE .BORDERLESS_WINDOWED_MODE .WINDOW_HIGHDPI.

Input

The enum type is inferred, so write rl.IsKeyDown(.SPACE). Key names are the raylib ones with KEY_ stripped: .LEFT .RIGHT .UP .DOWN .SPACE .ENTER .ESCAPE .A .Z .ZERO .NINE .LEFT_SHIFT .F1. Mouse buttons are .LEFT .RIGHT .MIDDLE.

IsKeyDown vs IsKeyPressed is the distinction that causes the most bugs. Movement wants Down. Jumping, shooting, opening a menu want Pressed.

Drawing shapes

Everything draws from the top-left and the y-axis points down. To centre a PLAYER_SIZE box on pos, draw at pos - PLAYER_SIZE/2.

Text

Drawing a number requires a cstring, and core:fmt has one built for exactly this:

import "core:fmt"

label := fmt.ctprintf("Score: %v", score)
rl.DrawText(label, 8, 8, 20, rl.BLACK)

ctprintf allocates from the temp allocator, so call free_all(context.temp_allocator) once at the end of every frame.

Textures

DrawTexturePro is the one that does everything: source picks a sub-rectangle of the image (this is how sprite sheets work), dest places and scales it, origin sets the pivot for rotation. Use rl.WHITE as tint to draw unmodified.

Textures need a GPU context, so load them after InitWindow, not before.

Collision

GetCollisionRec is how you resolve a collision rather than just detect it: the returned rectangle tells you how deep the overlap is on each axis, and you push out along the shallower one.

Camera

camera := rl.Camera2D{ zoom = 1 }        // zoom = 0 draws nothing. Set it.

camera.target = player                    // follow the player
camera.offset = {WINDOW_WIDTH/2, WINDOW_HEIGHT/2}

rl.BeginMode2D(camera)
	// world-space drawing
rl.EndMode2D()
// screen-space drawing (HUD) goes here, outside the camera

GetScreenToWorld2D(position, camera) converts a mouse position into world space — essential the moment the camera moves. GetWorldToScreen2D goes the other way.

Audio

Short effects are Sound (decoded into memory). Long tracks are Music (streamed).

Vector maths

The bindings ship a raymath.odin, but prefer Odin’s own core:math/linalg. Because Vector2 is just [2]f32, linalg works on it directly, and around a third of raymath’s procedures are now marked deprecated in favour of a linalg equivalent — rl.Vector2Lerp compiles with a warning telling you to use linalg.lerp.

import "core:math"
import "core:math/linalg"

dir  := linalg.normalize0(target - player)   // 0 version is safe on a zero vector
dist := linalg.length(target - player)
mid  := linalg.lerp(a, b, 0.5)
ang  := math.atan2(dir.y, dir.x)

x := clamp(player.x, 0, WINDOW_WIDTH)        // builtin, no import

Where to look things up

• raylib cheatsheet — every function, one page.
• raylib examples — ~150 runnable programs in C.
• pkg.odin-lang.org/vendor/raylib — generated Odin docs.

Related: Odin cheatsheet · Lesson 1 · Lesson 2